@echo off
if %1.==. goto defaut
if %1==? goto syntaxe
set sectW95=%1
goto S1 
:defaut
set sectW95=C:\BOOTSECT.DOS
:S1
echo Sauvegarde du multiboot
if exist %sectW95% goto S2
echo Fichier image %sectW95% inexistant
goto fin
:S2
echo Inserer une disquette vierge et formatee dans le lecteur A:
pause
set sect=A:\BOOTSECT.NT
set dbgcmd=C:\CMDDBG.TXT
echo Sauvegarde du secteur de boot dans %sect%
c:
cd \
REM creation du fichier de commandes debug
echo l 100 2 0 1 > %dbgcmd%
echo n %sect% >> %dbgcmd%
echo r cx >> %dbgcmd%
echo 200 >> %dbgcmd%
echo w >> %dbgcmd%
echo q >> %dbgcmd%
debug < %dbgcmd% >nul
echo Copie des fichiers de NT/W2K/NT :
attrib -r -h -s C:\*.*
if exist C:\NTLDR goto S3
echo Fichier C:\NTLDR inexistant
goto fin
:S3
if exist C:\NTDETECT.COM goto S4
echo Fichier C:\NTDETECT.COM inexistant
goto fin
:S4
if exist C:\BOOT.INI goto S5
echo Fichier C:\BOOT.INI inexistant
goto fin
:S5
copy C:\NTLDR a: >nul
Echo    copie de NTLDR
copy C:\NTDETECT.COM A: >nul
Echo    copie de NTDETECT.COM
copy C:\BOOT.INI A: >nul
Echo    copie de BOOT.INI
if not exist C:\BOOTFONT.BIN goto S6
copy C:\BOOTFONT.BIN A: >nul
Echo    copie de BOOTFONT.BIN
:S6
if not exist C:\NTBOOTDD.SYS goto S7
copy C:\NTBOOTDD.SYS A: >nul
Echo    copie de NTBOOTDD.SYS
:S7
copy %sectW95% A: >nul
Echo Copie du fichier image %sectW95%
Echo Fin de la sauvegarde
goto fin
:syntaxe
echo Syntaxe :
echo    savemult [fichier_image]
echo Parametre :
echo    fichier_image : nom du fichier image de secteur de boot DOS/Windows 9X
echo                    ne rien mettre si c'est C:\BOOTSECT.DOS
:fin